home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-20
/
nos_kit.zip
/
FINISH.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-03-01
|
3KB
|
108 lines
echo off
rem ==========================================================================
rem
rem F I N I S H . B A T
rem
rem Copyright 1991 Dave Fritsche (wb8zxu)
rem All rights reserved.
rem Non-profit redistribution is allowed
rem
rem This batch file is run after the install program has created all the
rem needed subdirectories, and unique configuration files. The command
rem line parameters passed to this batch file are:
rem %1 - The drive that contains the distribution files (e.g. a:)
rem %2 - Directory path to the install files on the dist. drive
rem %3 - The target drive for the installation (e.g. c:)
rem %4 - The target drive's base directory for installing NOS
rem %5 - Same as %2, except no trailing "\"
rem %6 - "ka9q" if ka9q-nos is to be installed
rem %7 - "g1emm" if g1emm-nos is to be installed
rem %8 - "bm" if the BM mailer is to be installed
rem %9 - "netnews" if the NETNEWS software is to be installed
rem ==========================================================================
rem
rem ----------------------------
rem Change to the "target" drive
rem ----------------------------
%3
if %6X==ka9qX goto INSNOS
if not %7X==g1emmX goto NONOS
:INSNOS
rem ------------------------------
rem Install the mailbox help files
rem ------------------------------
cd %4
cd spool\help
%1%2unzip %1%2nos_misc help/*.*
rem -------------------------
rem Install the documentation
rem -------------------------
cd %4
cd pub\doc
%1%2unzip %1%2nos_misc doc/*.*
rem -------------------------------
rem Install the KISS TNC ROM images
rem -------------------------------
cd %4
cd pub\kiss
%1%2unzip %1%2nos_misc kiss/*.*
rem ------------------------------------------------------------------------
rem Install the uudecoder sources for mailbox users (usefull for DU command)
rem ------------------------------------------------------------------------
cd %4
cd pub\uudecode
%1%2unzip %1%2nos_misc uudecode/*.*
rem ----------------------------------------
rem Install the KA9Q executable if requested
rem ----------------------------------------
if not %6X==ka9qX goto NOKA9Q
cd %4
cd bin
%1%2unzip %1%2nos_exe nos1130d.exe
ren nos1130d.exe noska9q.exe
cd %4
cd pub\doc
%1%2unzip %1%2nos_exe nos1130d.doc
ren nos1130d.doc noska9q.txt
:NOKA9Q
rem -----------------------------------------
rem Install the G1EMM executable if requested
rem -----------------------------------------
if not %7X==g1emmX goto NOG1EMM
cd %4
cd bin
%1%2unzip %1%2nos_exe b_113016.exe
ren b_113016.exe nosg1emm.exe
cd %4
cd pub\doc
%1%2unzip %1%2nos_exe b_113016.doc
ren b_113016.doc nosg1emm.txt
:NOG1EMM
rem
:NONOS
rem ------------------------------------
rem Install BM mail program if requested
rem ------------------------------------
if not %8X==bmX goto NOBM
cd %4
cd bin
%1%2unzip %1%2nos_exe bm.exe
:NOBM
rem -------------------------
rem Install the misc utilites
rem -------------------------
if %6X==ka9qX goto INSMISC
if %7X==g1emmX goto INSMISC
if not %9X==netnewsX goto NOMISC
:INSMISC
cd %4
cd bin
%1%2unzip %1%2nos_misc misc_bin/*.*
:NOMISC
rem -------------------------------------------------------
rem All done. Change back to the distribution disk and dir
rem -------------------------------------------------------
:END
%1
cd %5